Сила прижима пластины к электромагниту равна нулю - (тестовый пример из мануала) ANSYS APDL

Взял готовый пример из ANSYS Low-Frequency Electromagnetic Analysis Guide.pdf Старинца 2-28 (63) заголовок "2.4. Doing an Example 2-D Static Magnetic Analysis (GUI Method)" Там же на стр.2-30 (65) дан текст на языке APDL. все прекрасно считается. Аналог с описанием на русском языке есть здесь  на стр. 91. Линии поля идут через пластину которая примыкает к электромагниту сверху. НО выбираем пластину и ставим команду в конце PLNSOL, FMAG,SUM, 0 и НИКАКИХ СИЛ НА ЭТОЙ ПЛАСТИНЕ НЕТ!!!. Такого не может быть. Электромагнит должен хоть что-то притягивать. В чем дело?

Есть ли вообще где-то в природе простой пример: катушка электромагнита , пусть с сердечником и пластина сверху над катушкой с расчетом сил притяжения к катушке. Нужен только ANSYS APDL у нае есть на него лицензия. На максвелла нет.

Для ленивых привожу текст из мануала кода здесь:

!/batch,list
/PREP7
/TITLE, 2-D Solenoid Actuator Static Analysis
ET,1,PLANE53 ! Define PLANE 53 as element type
KEYOPT,1,3,1 ! Use axisymmetric analysis option
MP,MURX,1,1 ! Define material properties (permeability)
MP,MURX,2,1000 ! Permeability of backiron
MP,MURX,3,1 ! Permeability of coil
MP,MURX,4,2000 ! Permeability of armature
/com, ! Set parameter values for analysis
n=650 ! Number of coil turns
i=1.0 ! Current per turn
ta=.75 ! Model dimensions (centimeters)
tb=.75
tc=.50
td=.75
wc=1
hc=2
gap=.25
space=.25
ws=wc+2*space
hs=hc+.75
w=ta+ws+tc
hb=tb+hs
h=hb+gap+td
acoil=wc*hc ! Cross-section area of coil (cm**2)
jdens=n*i/acoil ! Current density (A/cm**2)
/PNUM,AREA,1

RECTNG,0,w,0,tb ! Create rectangular areas
RECTNG,0,w,tb,hb
RECTNG,ta,ta+ws,0,h
RECTNG,ta+space,ta+space+wc,tb+space,tb+space+hc
AOVLAP,ALL
RECTNG,0,w,0,hb+gap
RECTNG,0,w,0,h
AOVLAP,ALL
NUMCMP,AREA ! Compress out unused area numbers
APLOT
ASEL,S,AREA,,2 ! Assign attributes to coil
AATT,3,1,1,0
ASEL,S,AREA,,1 ! Assign attributes to armature
ASEL,A,AREA,,12,13
AATT,4,1,1
ASEL,S,AREA,,3,5 ! Assign attributes to backiron
ASEL,A,AREA,,7,8
AATT,2,1,1,0
/PNUM,MAT,1 ! Turn material numbers on
ALLSEL,ALL
APLOT ! Plot areas
SMRTSIZE,4 ! Set smart size meshing level 4 (fine)
AMESH,ALL ! Mesh all areas
ESEL,S,MAT,,4 ! Select armature elements
CM,ARM,ELEM ! Define armature as a component
FMAGBC,'ARM' ! Apply force boundary conditions to armature
ALLSEL,ALL
ARSCAL,ALL,,,.01,.01,1,,,1 ! Scale model to MKS (meters)
FINISH
/SOLU
ESEL,S,MAT,,3 ! Select coil elements
BFE,ALL,JS,1,,,jdens/.01**2 ! Apply current density (A/m**2)
ESEL,ALL
NSEL,EXT ! Select exterior nodes
D,ALL,AZ,0 ! Set potentials to zero (flux-parallel)
ALLSEL,ALL
FINISH
/SOLU
MAGSOLV ! Solve magnetic field
SAVE
FINISH
/POST1
PLF2D ! Plot flux lines in the model
FMAGSUM ! Summarize magnetic forces
PLVECT,B,,,,VECT,ELEM,ON ! Plot flux density as vectors
/GRAPHICS,POWER ! Turn PowerGraphics on
AVRES,2 ! Don't average results across materials
PLNSOL,B,SUM ! Plot flux density magnitude

! Выбрать элементы пластины  или вообще всего без катушки

ESEL,U,MAT,,3 ! UnSelect coil elements

PLNSOL, FMAG,SUM, 0

FINISH